// Scilab code developed by:
// International Research Institute for Climate and Society
// Columbia University in the City of New York, USA
// Last update: June 26, 2013
// --------------------------------------------------------------------------------------------------------
// Dependancies : (see each function for further details)
//      -- infected_init.sci for basic computation of the models
//      -- Definition of the oving parameters
// --------------------------------------------------------------------------------------------------------
// Functions :
//      -- returns a matrix, each column being the answer of the model to one of the 9 sets of parameters
// --------------------------------------------------------------------------------------------------------


function[EI]=infected_ensemble(param,ti,tf,XXX)

    select XXX // Define the two parameters you want to vary to create the ensemble
    case "WCT"
        PaVar1=5; PaVar2=14; // alpha and g_n
    case "MAC"
        PaVar1=1; PaVar2=8; // alpha and l
    case "AM"
        PaVar1=1; PaVar2=8; // alpha and l
    case "ABP"
        PaVar1=7; PaVar2=14; // r_0 and initial condition
    end
    
    EI=[];

    for Pa1 = [param(PaVar1)*(1-1/10),param(PaVar1),param(PaVar1)*(1+1/10)]
        for Pa2 = [param(PaVar2)*(1-1/10),param(PaVar2),param(PaVar2)*(1+1/10)]
            param_ens=param;
            param_ens(PaVar1)=Pa1;
            param_ens(PaVar2)=Pa2;
            EI=[EI,infected_init(param_ens,ti,tf,XXX)];
        end
    end

endfunction